Kinglong's Blog-[AS3]URLLoader+URLRequest+JPGEncoder实现BitmapData图片数据保存

[AS3]URLLoader+URLRequest+JPGEncoder实现BitmapData图片数据保存
这段时间工作忙，一直抽不出空来写点内容。今天晚上正好能静下心来，把工作中用到Flash位图数据保存整理一下，写了下面的应用实例。
Flash客户端代码(test12.swf)

package project.test {
	
	import flash.display.*;	
	import flash.net.*;
	import flash.events.*;
	import flash.utils.ByteArray;
	
	import fl.controls.Button;
	
	import com.klstudio.images.JPGEncoder;
	
	public class Test12 extends Sprite{
		private var _base:Shape;
		private var _rnd_button:Button;
		private var _submit_button:Button;
		
		private static const UPLOAD_PAGE:String="http://localhost:8080/upload.jsp"; 
		
		public function Test12(){			
			_base = new Shape();
			_base.x = _base.y = 5;
			addChild(_base);			
			drawLine();		
			
			_rnd_button = new Button();
			_rnd_button.label = "随机画图";
			_rnd_button.setSize(90,22);
			_rnd_button.move(5,205);
			_rnd_button.addEventListener(MouseEvent.CLICK,clickHandler);
			addChild(_rnd_button);
			
			_submit_button = new Button();
			_submit_button.label = "保存图片";
			_submit_button.setSize(90,22);
			_submit_button.move(105,205);
			_submit_button.addEventListener(MouseEvent.CLICK,clickHandler);
			addChild(_submit_button);
		}
		
		public function drawRndRect():void{
			_base.graphics.beginFill(getRndColor());
			var gWidth:uint = getRndInt();
			var gHeight:uint = getRndInt();
			var gX:uint = getRndInt(5,180-gWidth+5);
			var gY:uint = getRndInt(5,180-gHeight+5);
			_base.graphics.drawRect(gX,gY,gWidth,gHeight);			
		}
		
		public function getRndInt(min:uint=10,max:uint=180):uint{
			return uint(Math.random()*(max-min))+min;
		}
		
		public function getRndColor():uint{
			var r:uint = getRndInt(10,220);
			var g:uint = getRndInt(10,220);
			var b:uint = getRndInt(10,220);
			var c:uint = (r << 16) + (g << 8) + b;
			return c;
		}
		
		public function drawLine():void{			
			_base.graphics.beginFill(0x666666);
			_base.graphics.drawRect(0,0,190,190);
			_base.graphics.beginFill(0xFFFFFF);
			_base.graphics.drawRect(1,1,188,188);
			_base.graphics.endFill();
		}
		
		public function getBitmapData():BitmapData{
			var bmd:BitmapData = new BitmapData(_base.width,_base.height);
			bmd.draw(_base);
			return bmd;
		}
		
		public function submit():void{
			_rnd_button.enabled = false;
			_submit_button.enabled = false;
			var encoder:JPGEncoder = new JPGEncoder(80);
			var bytes:ByteArray = encoder.encode(getBitmapData());
			var request:URLRequest = new URLRequest(UPLOAD_PAGE);
			//data值就为图片编码数据ByteArray;
			request.data = bytes;
			request.method = URLRequestMethod.POST;
			//这个是关键,内容类型必须是下面文件流形式;
			request.contentType = "application/octet-stream";
			
			var loader:URLLoader = new URLLoader();			
			loader.addEventListener(Event.COMPLETE, completeHandler);
			loader.addEventListener(IOErrorEvent.IO_ERROR,errorHandler);
			loader.load(request);
		}
		
		private function completeHandler(event:Event):void{
			trace("图片上传成功");
			_rnd_button.enabled = true;
			_submit_button.enabled = true;
		}
		
		private function errorHandler(event:IOErrorEvent):void{
			trace("图片上传失败");
			_rnd_button.enabled = true;
			_submit_button.enabled = true;
		}
		
		private function clickHandler(event:MouseEvent):void{
			switch(event.target){
				case _rnd_button:
					_base.graphics.clear();
					drawLine();
					drawRndRect();
					drawRndRect();
					drawRndRect();
					drawRndRect();
					break;
				case _submit_button:
					submit();
					break;
			}
		}
	}	
}

服务端代码(upload.jsp)：我使用是Java服务端，当然PHP,ASP.NET也可以了，我在这里就不一一举例了，有兴趣的朋友自己研究了！

相关实例文件打包下载：http://www.klstudio.com/demo/test/test12.rar

Trackback:

TrackBack URL for this entry:
http://www.klstudio.com/cmd.asp?act=tb&id=141

Comments:

不错.
除了使用通常意义上的后台语言外,还可以利用FMS生成.

想问一下这个要是生成一张800*600的图片大概需要多长时间,有没有什么办法让图片生成在本地.

不错哦！这方面高手哦！
虽然看不懂
不过还是要支持你哈！

to 西部秋虫:能用后台页面的方式,一般就不建议再用FMS了,那个东西用来做语音和视频通信比较适合!

to kevin:这个你可以自己测试一下吧.
flash图片本地生成,如果借助外壳程序来实现的话,光flash player是不可能的

里面的JPGEncoder类是根据什么编写的？
根本看不懂！

http://www.vistaprint.com/vp/ns/studio3.aspx?pf_id=088&cfs=-1&combo_id=5946&icparts=yes&combo1=910.88.1.14205%7c14205%7c137%7c0&category_id=10318&gallery_id=206&referer=http%3a%2f%2fwww.vistaprint.com%2fvp%2fns%2fgallery.aspx%3fg%3d206

高手,真是太激动了!
上面那个网址你点开后,实际上是一个名片的网上设计:他利用已有模板,用户可以随意编辑,最后服务器生成一个印刷精度(300DPI)的图片,请问,您能实现这个功能吗?
如果愿意于我联系,请加我的MSN或电话13701868025

to youxiazhu:
这个国外有人参照jpg编码器写的,对你来说,只要调用就可以了!如果你不是专门研究图形学的话,就没有必要清楚那么多吧!

to dagang:
理论上是用flash来实现的!当然只要价格合适,我这边可以来开发的!

kinglong
很荣幸看到你的教程，我现在已经修改成.NET的了，C#我也不是很精通，但现在可以实现生成图片了。

有个问题。
你这个实现了抓拍图片，但是，图片的附加信息，应该怎么发送出去啊？我对二进制一点也不了解，也不知道如何把附加信息加进入，并发送给后台！
希望进步讲解一下！谢谢

问题基本同上吧，我弄了个ASP后台，我想从前台将要保存的文件名传给后台，怎么传呀，Flash端只能Post Binary数据给后台,String怎么传过去呀？！！！

附加信息，目前只能通过get方式来传递;
做法就是把在上传地址改成http://..../upload.jsp?name=xxxxx&title=xxxxx
也就是说图片数据是通过post方式，其他参数就是get方式了

提供一个asp.net的后台生成图片的好吗，谢谢！

很不错，刚开始还打算，在后台在生成一次了，想不到能直接保存图片格式。
其实我也想过，但是一直没有找到什么好的方法。
谢谢了

请问UPLOAD_PAGE的URL可以通过外部传递取得吗？

可以的，在加载swf的时候通过xxx.swf?page=http://xxx.xxx.xx
然后在flash里面是通过loaderInfo.parameters.page来获取传进来的参数。

Kinglong's Blog

Navigation

[AS3]URLLoader+URLRequest+JPGEncoder实现BitmapData图片数据保存

Trackback:

Comments:

Post a comment:(为了防止垃圾留言信息,您的留言需要通过审核才能显示出来)

最近发表

最新留言

文章归档