Kinglong's Blog-[AS2]Flash版本的Cookie类

[AS2]Flash版本的Cookie类

利用Flash的SharedObject类的功能，来模拟Cookie的功能！

/**
* @link http://www.klstudio.com
* @author Kinglong
* @usage flash player 7
* @version 0.1
*/

class  as2.util.Cookie {
	
	private var _time:Number;
	private var _name:String;
	private var _so:SharedObject;
	
	public function Cookie(name:String,time:Number){		
		_name = (name == undefined)?"klstudio":name;
		_time = (time == undefined)?36000:time;
		_so = SharedObject.getLocal(_name,"/");
	}
	
	public function clearTimeOut():Void{
		var obj:Object = _so.data.cookie;
		if(obj == undefined){
			return;
		}
		for(var key in obj){
			if(obj[key] == undefined || obj[key].time == undefined || isTimeOut(obj[key].time)){
				delete obj[key];
			}
		}
		_so.data.cookie = obj;
		_so.flush();
	}
	private function isTimeOut(time:Number):Boolean{
		var today:Date = new Date();		
		return time + _time * 1000 < today.getTime();
	}
	
	public function getTime():Number{
		return _time;
	}	
	public function getName():String{
		return _name;
	}
	public function clear():Void{
		_so.clear();
	}	
	public function put(key:String,value:Object):Void{
		var today:Date = new Date();
		key = "key_"+key;
		value.time = today.getTime();
		if(_so.data.cookie == undefined){
			var obj:Object = {};
			obj[key] = value;
			_so.data.cookie = obj;
		}else{
			_so.data.cookie[key] = value;
		}
		_so.flush();
	}
	public function remove(key:String):Void {
		if (contains(key)) {
			delete _so.data.cookie["key_" + key];
			_so.flush();
		}
	}
	public function get(key:String):Object{		
		return contains(key)?_so.data.cookie["key_"+key]:null;
	}	
	public function contains(key:String):Boolean{
		key = "key_" + key;	
		return _so.data.cookie != undefined && _so.data.cookie[key] != undefined;
	}
}

调用实例

Trackback:

TrackBack URL for this entry:
http://www.klstudio.com/cmd.asp?act=tb&id=162

Comments:

谢谢，有用

有as3.0版的吗

Kinglong's Blog

Navigation

[AS2]Flash版本的Cookie类

Trackback:

Comments:

Post a comment:(为了防止垃圾留言信息,您的留言需要通过审核才能显示出来)

最近发表

最新留言

文章归档